《剑网3》和尚技能与奇穴二次调整解析

　　根据以上的分析，逐鹿中原版本的易经和尚的输出手法有一定的改动，通过测试来看新的输出方式相较于老的输出要高8-10%（带buff的实战数据，不包含技能加成）左右，因此，不加以改变的话输出能力将会有很大差距。在这里放出适用新版技能和奇穴的宏，欢迎大家使用并反馈意见：

#name 汪老湿易经宏
#Hello 欢迎使用汪老湿易经宏v1.1 for 逐鹿中原，如有问题请与汪老湿@电三太极广场联系
#icon 4930
#delay 1

#varbox name:v_syyz,type:bool,tip:特效腰坠,tip_1:使用腰坠,tip_2:不使用腰坠,icon:2842
#varbox name:v_dd,type:num_2,tip:打断模式,tip_1:打断,tip_2:不打断,icon:1511,icon_2:1817
#varbox name:v_hc,type:num_2,tip:后跳模式,tip_1:自动后跳,tip_2:不自动后跳,icon:1491,icon_2:1817
#varbox name:v_fy,type:num_2,tip:扶摇模式,tip_1:不自动补扶摇,tip_2:自动补扶摇,icon:1817,icon_2:1485
#varbox name:v_hwq,type:num_3,tip:换武器模式,tip_1:双445,tip_2:三刀流,tip_3:不换武器,icon:4779,icon_2:3976,icon_3:1817
#varbox name:v_sqms,type:num_2,tip:守缺模式,tip_1:速叠众嗔,tip_2:顺其自然,icon:2972,icon_2:1817
#varbox name:v_cw,type:num_2,tip:橙武buff使用,tip_1:无限韦陀,tip_2:韦陀拿云交替,icon:419,icon_2:428

#skillbox 无相诀,擒龙诀,亦枯亦荣,横扫六合,捉影式

--QTE
/skill QTE

--苏曼莎反弹和黑齿小怪自动停手,无目标时也停止运行宏，防止浪费金刚和擒龙
/return [tbuff:御受|金蛇盘巢]
/return [!fight,!tar]

--扶摇直上自动开
/skill [fight,v_fy=2]扶摇直上

--危险状态下，开无相
/skill [life<0.4,fight,nobuff:渊&镇山河&春泥护花&圣手织天&蝶戏水&天地低昂&舍身]无相诀
/skill [tpre:狼之怒|藏离精失,nobuff:弹跳,nobuff:镇山河&春泥护花&圣手织天&蝶戏水&天地低昂]无相诀

--刚开擒龙诀或触发雷特效时开腰坠
/use [buff:4759,buff:金刚怒目;buff:1378]腰坠

--战宝与大明宫自动后跳
/if [v_hc=1]
/skill [map:英雄战宝军械库|战宝军械库,target:卓力格图,nobuff:镇山河,tprepare:掷锤>0.5] 后撤
/skill [map:英雄大明宫|大明宫,target:何莘涯,nobuff:镇山河,tprepare:吞云吐纳>0.7] 后撤
/end

--佛心好了就开
/skill [fight,nobuff:九襄地玄五阵&金刚伏魔五阵&引羌笛&极乐]佛心诀

/if [v_cw=1]
--有CWBUFF，无限韦陀
/skill [buff:1919]韦陀献杵
/elseif [v_cw=2]
--有CWBUFF，交替韦陀拿云
/skill [buff:1919,nav=3]拿云式
/skill [buff:1919]韦陀献杵
/end

--双445武器切换
/if[v_hwq=1]
/omwp [buff:6394]禅机棍
/omwp [nobuff:6394]寂净谛观
/end
--三刀流,仅在gcd时间内切295武器利用平砍叠buff
/if[v_hwq=2,buff:6394]
/omwp [(bufftime:水·痛切<3;nobuff:水·痛切),ggcd<1.3,ggcd>0.2,sktest:六合棍]禅心伏明
/omwp [ggcd<0.2]禅机棍
/elseif[v_hwq=2,nobuff:6394]
/omwp [(bufftime:水·痛切<3;nobuff:水·痛切),ggcd<1.3,ggcd>0.2,sktest:六合棍]禅心伏明
/omwp [ggcd<0.2]寂净谛观
/end

--需要打断的情况下抢珠
/skill [v_dd=1,tprepare,sktest:抢珠式] 抢珠式

--记录禅那，之所以记录禅那，是因为放了技能之后，下一个技能就已经准备好释放了，那时候判断禅那会有一定延迟
/var [nav] v_nav

--开怪首先金刚怒目消耗掉豆，然后守缺式
/skill [nobuff:守缺,sktest:守缺式,cdtime:守缺式<0.2,nav=3,cdtime:金刚怒目<0.2]金刚怒目
/skill [nobuff:守缺,cdtime:守缺式<0.2] 守缺式

--↓*********无GCD技能部分***********↓
--无相诀之后不开爆发
/if [!expcast:无相诀]
--优先金刚怒目，后擒龙诀
/skill [v_nav=3,fight,sktest:守缺式,cdtime:金刚怒目<0.2,nobuff:1919,cd0<0.6,nobuff:三生]金刚怒目
/var [sklv:金刚怒目>0,explast:金刚怒目,0;v_nav]v_nav--释放金刚怒目之后，禅那归零

/if [!banskill:擒龙诀,cd0<0.6,fight,sktest:守缺式,cdtime:擒龙诀<0.2]
/skill [v_nav=1,fight,cdtime:亦枯亦荣<0.2,nowtime-(v_wtxc;0)<1.5,nobuff:擒龙诀] 亦枯亦荣,擒龙诀
/skill [v_nav<=1,nobuff:擒龙诀]擒龙诀
/end

/var [explast:擒龙诀,3;v_nav]v_nav--释放擒龙诀之后，禅那变成3
--擒龙诀之后，如果金刚怒目好了，优先金刚怒目
/skill [v_nav=3,fight,tlife<1,sktest:守缺式,cdtime:金刚怒目<0.2,nobuff:1919,nobuff:三生,(nobuff:擒龙诀,cd0<0.6;buff:擒龙诀)]金刚怒目
/var [sklv:金刚怒目>0,explast:金刚怒目,0;v_nav]v_nav--释放金刚怒目之后，禅那归零
/end

--有捕风式buff，并且可以释放捉影式的时候，释放捉影式
/skill [v_nav<3,buff:捕风式,sktest:捉影式,cdtime:捉影式<0.2] 捉影式

--释放捉影式之后，禅那加一
/var [explast:捉影式,v_nav+1;v_nav]v_nav

--擒龙诀和金刚怒目同时，存在，使用腰坠
/skill [buff:弱水&金刚怒目,v_syyz]腰坠

--缺蓝就不等擒龙诀，直接开亦枯亦荣了
/skill [mana<0.2,v_nav=1,fight,tlife<1,sktest:守缺式,cdtime:亦枯亦荣<0.2,cd0<0.6]亦枯亦荣

--开爆发时禅那溢出，同样可以使用亦枯亦荣
/skill [mana<0.6,v_nav=1,fight,tlife<1,sktest:守缺式,cdtime:亦枯亦荣<0.2,buff:擒龙诀]亦枯亦荣

--↓***********有GCD技能部分***********↓
--擒龙诀回豆的判定，如果擒龙诀buff存在的时候，擒龙诀buff的时间接近回豆的时间了，预判回1豆
/var [(bufftime:擒龙诀;18)<17,(bufftime:擒龙诀*10)%15] v_qlj
/if [v_qlj,(v_qlj<0.5),v_nav+1]--时间限制为0-1
/if [!v_added]--时间段内只加一次
/var [v_nav+1] v_nav
/var [true] v_added
/end
/else--时间段外重置加法判定变量
/var [false] v_added
/end

--如果禅那预想值大于等于3，优先拿云，之后韦陀。
--判断拿云后的一豆
/skill [v_nav>=3,tlife<=0.3,cdtime:拿云式<0.2]拿云式
/if [explast:拿云式,recipe:《龙爪功·拿云式》人偶图残页]
/var [nowtime] v_wtxc
/end
--判断韦陀后的一豆
/skill [v_nav>=3,tlife>0.3,cdtime:韦陀献杵<0.2]韦陀献杵
/if [explast:韦陀献杵,recipe:《罗汉棍法·韦陀献杵》人偶图残页]
/var [nowtime] v_wtxc
/end

--众嗔未叠满时，优先打守缺
/if[v_sqms=1]
/skill [buff:众嗔<5,v_nav<3]守缺式
/end

--点了众嗔奇穴的情况下，众嗔快断了的时候，补一个守缺
/skill [cdtime:守缺式<0.2,sklv:6596=1,(bufftime:众嗔;3)<2]守缺式

--未点断灭时，周围小怪大于等于3个时，横扫优先级高于3豆韦陀
/if [!sklv:5899=1,v_nav=3,tlife>0.3,sktest:韦陀献杵]
/skill [emdis:5>2]横扫六合
/end

--上述技能结束后优先横扫,守缺,普渡,恒河劫沙，然后捕风
/skill [fight,tar,(sktest:普渡四方;distance<=5;(tar:傀儡·天,dis<=6))] 横扫六合
/skill 守缺式
/skill [v_nav<3]普渡四方
/skill [v_nav<3]恒河劫沙
/skill [(!sktest:守缺式;cdtime:守缺式>1.2,!sktest:普渡四方),tar,(sklv:5911~=1;V_dd=2)]捕风式