|
剑网3楠桥雪纯阳宏 剑纯宏气纯宏单独拆解 只是应喜欢我宏的那部分人要求放出目前我自己写的纯阳宏，他们觉得双心法宏虽然不错。但是自己是单休的，根本没必要。
气纯宏在最下面，回复获取，不想回复的就在上面拿，去掉解释就行了。
因为气纯宏是我最近才接触的，所以解释下我写命令的思路。剑纯部分就不写了，直接粘贴。
剑网3楠桥雪纯阳宏剑纯奇穴：[心固][深埋][碎星辰][元剑][抱元守缺][叠刃][凌太虚][无欲][和光][物我两忘]
剑网3楠桥雪纯阳宏气纯奇穴：[白虹][心固][破苍穹][无形][抱元守缺][太极][跬步][万物][气竭][期声]
气纯第二个奇穴你们想选另一个也可以，但是我觉得没必要，气纯不应该嫌豆多！
一个队伍里如果有2个人用我的宏是一种悲剧，我宏的气场一直以别人宏的设置空隙来设置，竭尽全力把气场蹭到底。
#skillbox 扶摇直上:off,凭虚御风
技能开关：扶摇直上，默认关闭。凭虚御风，默认开启
#var name:气场,desc:气场总控,icon:618
气场开关，默认开启。
#var name:爆发,desc:爆发总控,icon:2933
爆发开关，默认开启
/skill [threat>0.8]凭虚御风
凭虚御风仇恨设置，仇恨大于80%释放。可在最上面关闭！
/skill [mana<0.4,qidian>9,nobuff:紫气东来-风·灭气-流蓝,nolastota:万世不竭,fight]抱元守缺
回蓝设置，蓝小于40%，5个豆，没有状态紫气东来，特效腰坠，天狼掉蓝的战斗状态，上一次读条不是万世的时候释放，避免豆的判断延迟，不够豆就在释放，保证回蓝量60%！
/skill 万世不竭
万世好了就释放
/skill 太极无极
太极好了就释放
/skill [qidian>7,cdtime:万世不竭>1.4,(mana>0.4;cdtime:抱元守缺>1)]两仪化形
两仪气点至少4个豆，并且万世冷却至少剩余1.5秒的时候，要么蓝大于40%要么回蓝的抱元还在冷却才释放。保证抱元能准确的每次回蓝60%！
/skill [nobuff:紫气东来-风·灭气]扶摇直上
没有爆发的时候自动开扶摇，因为位置问题所以默认是小于4个豆才释放，如果因为距离或方向原因导致其他技能卡住了，5豆了依然能释放，不会因为输出环境而限制释放。
/skill [qidian>8,status:jump-run]两仪化形
移动或跳跃的时候最少4个半豆才释放两仪
/elseif [var_爆发,distance<20,tbuff:气竭>1,aura:破苍穹>11,tmaxlife>4900000]
爆发前置条件，距离小于20.气场至少12秒，目标气竭至少2层，目标血量大于490W！考虑到气场BUFF获得后没气场也会存在才设置这么低。
/skill [buff:风·灭气,qidian<6;qidian<5]韬光养晦.
在前置条件满足的情况后，特效腰坠状态小于3个豆或者平时小于2个半豆用韬光回豆，后一个条件可以设置成3或4。主要是怕有人两仪是回豆的那个秘籍，气点几乎都是2个。所以这里以他们为参考设置！
/skill [qidian>7,mana>0.15]紫气东来
在前置条件满足的情况后，4个豆，蓝大于15%释放紫气
/item [qidian>7,mana>0.15]灵南坠
在前置条件满足的情况后，4个豆，蓝大于15%释放特腰坠。
/end
/skill [var_气场,(nobuff:风·灭气-紫气东来-破苍穹;var_爆发,cdtime:紫气东来<2,tbuff:气竭>1,aura:破苍穹<9)]破苍穹
没有特效腰坠，没有紫气，没有破苍穹的任何一个状态的时候释放破苍穹，默认需要小于4个豆，同扶摇一样。如果因为其他原因输出技能无法释放的时候，不会因为气点原因而卡住不释放。同样不会被环境所限制！以及在紫气快好的时候，气竭至少2层，破苍穹时间不够了也会补一个气场方便爆发开启。关闭爆发后，补气场也会关闭，不会乱插气场。
/skill [qidian<9,cdtime:万世不竭>2,nolastota:四象轮回]四象轮回
小于4个半豆的时候，万世冷却大于2秒，只允许读一次四象，不允许重复读。
/skill [qidian<8,cdtime:万世不竭<3;distance>20]四象轮回
万世冷却小于3秒或者已经CD好的时候，气点不够4个，直接打四象，或者距离超过20尺直接打四象。
/skill [cdtime:万世不竭<1,cdtime:万世不竭>0.4]四象轮回
最后这个四象只有在豆超过4个了，但是万世在冷却的时候用，但是限制很多。首先冷却时间要小于1秒，冷却时间又要最少0.5秒。这样如果剩下0.4秒，气点满了。四象不会打，会等0.4秒后直接打万世。
四象限制这么多就是因为延迟和电脑处理原因等个方面原因导致四象抢占其他技能的位置连读。
?
?
剑网3楠桥雪纯阳宏气纯部分
#skillbox 扶摇直上:off,凭虚御风
#var name:气场,desc:气场总控,ic />
#var name:爆发,desc:爆发总控,ic />
/omwp [nobuff:6394]云影涛声
/omwp [buff:6394]雨墨香
/skill [threat>0.8]凭虚御风
/skill [life<0.3,fight]转乾坤
/skill [prepare:无懈可击|天音化物|雨钓江秋|龙甩尾|怒吼|骑军令|急行军]剑飞惊天,天地无极
/skill [mana<0.41,qidian>9,nobuff:紫气东来-风·斩铁-流蓝,fight]抱元守缺
/skill [nobuff:紫气东来-风·斩铁,qidian<8]扶摇直上
/elseif [var_爆发,aura:碎星辰>13,distance<5,bufftime:剑气冲天>12,fight,tmaxlife>4900000]
/skill [buff:风·斩铁,qidian<5;qidian<3]韬光养晦
/skill [qidian>7;buff:风·斩铁]紫气东来
/item [qidian>7;buff:紫气东来]鼓宜坠
/elseif [qixue:叠刃]
/skill [mbufftime:叠刃<4]无我无剑
/skill [buff:北斗七星五阵,bufftime:北斗七星五阵<4]八荒归元,三环套月
/skill [tlife<0.5,cd:人剑合一]八荒归元
/skill [mbufftime:叠刃<6,qidian>5;qidian>7]无我无剑
/elseif [var_气场,nobuff:紫气东来|风·斩铁,tmaxlife>2000000]
/skill [(noaura:碎星辰;cdtime:人剑合一<4,nosaura:碎星辰;var_爆发,nocd:紫气东来,bufftime:剑气冲天>14,aura:碎星辰<15),distance<9]碎星辰
/skill [(cdtime:人剑合一<3,distance<9;distance>11),nosaura:凌太虚]凌太虚
/skill [saura:碎星辰,saura:凌太虚]人剑合一
/end
/skill 八荒归元
/skill [cdtime:八荒归元>2]天地无极
/skill 三环套月
/skill 三柴剑法
?
剑网3楠桥雪纯阳宏气纯部分
#skillbox 扶摇直上:off,凭虚御风
#var name:气场,desc:气场总控,ic />
#var name:爆发,desc:爆发总控,ic />
/skill [threat>0.8]凭虚御风
/skill [mana<0.4,qidian>9,nobuff:紫气东来-风·灭气-流蓝,nolastota:万世不竭,fight]抱元守缺
/elseif [var_爆发,distance<20,tbuff:气竭>2,aura:破苍穹>11,tmaxlife>4900000]
/skill [buff:风·灭气|紫气东来,qidian<6;qidian<5]韬光养晦
/skill [qidian>7,mana>0.15]紫气东来
/item [qidian>7,mana>0.15]灵南坠
/end
/skill 万世不竭
/skill 太极无极
/skill [qidian>7,cdtime:万世不竭>1.4,(mana>0.4;cdtime:抱元守缺>1)]两仪化形
/skill [nobuff:紫气东来-风·灭气]扶摇直上
/skill [qidian>8,status:jump-run]两仪化形
/skill [var_气场,(nobuff:风·灭气-紫气东来-破苍穹;var_爆发,cdtime:紫气东来<2,tbuff:气竭>1,aura:破苍穹<9)]破苍穹
/skill [qidian<9,cdtime:万世不竭>2,nolastota:四象轮回]四象轮回
/skill [qidian<8,cdtime:万世不竭<3;distance>20]四象轮回
/skill [cdtime:万世不竭<1,cdtime:万世不竭>0.4]四象轮回
?
[编辑：不详]
|
