修正金刚重叠无效 剑网3易经少林超级宏

修正金刚重叠无效 剑网3易经少林超级宏

　　剑网3安史之乱资料片已经开启有一段时间了，即将有重的更新便是血战天策，血战天策会出现全线的一个副本。在全线的副本内进行攻略的话，需要比较突出的DPS和机智的判断力，用一个好的超级宏可以帮助你更好的做到这一点，下面就是给大家带来的少林易经超级宏。

　　少林易经超级宏位于上下两分割线内。

　　———————————————————————————————————————————————————————————————————————

　　#name 少林易经超级宏第十六版

　　#tip 少林易经超级宏，修正金刚重叠无效的问题

　　#icon 3112

　　#varbox name:v_syyz,type:bool,tip:特效腰坠,tip_1:使用腰坠,tip_2:不使用腰坠,icon:2842

　　#varbox name:v_dd,type:num_2,tip:打断模式,tip_1:打断,tip_2:不打断,icon:1511,ICON_2:155

　　#skillbox 无相诀,金刚怒目,擒龙诀,亦枯亦荣,佛心诀,横扫六合,捉影式,扶摇直上

　　--扶摇直上自动开

　　/skill [fight]扶摇直上

　　--危险状态下，开无相

　　/skill [life<0.5,fight,nobuff:渊&镇山河&春泥护花&圣手织天&蝶戏水&风袖低昂&舍身]无相诀

　　--v_jgnm的作用：记录金刚怒目CD好的时刻

　　/if [nocd:金刚怒目,!v_jgnm]

　　/var [nowtime]v_jgnm

　　/elseif [cd:金刚怒目]

　　/var [false]v_jgnm

　　/end

　　/return [!tar]

　　--佛心好了就开

　　/skill [nobuff:九襄地玄五阵&金刚伏魔五阵&引羌笛&极乐]佛心诀

　　--先抢珠后捕风

　　/skill [v_dd=1,tprepare,sktest:抢珠式] 抢珠式

　　--点了5911([缘断])奇穴的时候，才释放捕风式打断

　　/skill [v_dd=1,tprepare,sklv:5911=1,sktest:捕风式] 捕风式

　　--开怪首先金刚怒目消耗掉豆，然后守缺式

　　/skill [nobuff:守缺式,sktest:守缺式,cdtime:守缺式<0.2] 金刚怒目,守缺式

　　--记录禅那，之所以记录禅那，是因为放了技能之后，下一个技能就已经准备好释放了，那时候判断禅那会有一定延迟

　　/var [nav] v_nav

　--*********无GCD技能部分***********

　　--无相诀之后不开爆发

　　/if [!lastcast:无相诀]

　　--优先金刚怒目，后擒龙诀

　　/skill [v_nav=3,fight,tlife<1,sktest:守缺式,nowtime-v_jgnm>0.1]金刚怒目

　　/var [sklv:金刚怒目>0,lastcast:金刚怒目,0;v_nav]v_nav--释放金刚怒目之后，禅那归零

　　--GCD在读到接近一半的时候，再开擒龙诀，此后，每次刷到一半就会回一个豆，判定可以很精确

　　/skill [cd0<1,cd0>0.5,v_nav=1,fight,tlife<1,sktest:守缺式,cdtime:擒龙诀<0.2]亦枯亦荣,擒龙诀

　　/var [lastcast:擒龙诀,3;v_nav]v_nav--释放擒龙诀之后，禅那变成3

　　--擒龙诀之后，如果金刚怒目好了，优先金刚怒目

　　/skill [v_nav=3,fight,tlife<1,sktest:守缺式,nowtime-v_jgnm>0.1]金刚怒目

　　/var [sklv:金刚怒目>0,lastcast:金刚怒目,0;v_nav]v_nav--释放金刚怒目之后，禅那归零

　　/end

　　--有捕风式buff，并且可以释放捉影式的时候，释放捉影式

　　/skill [v_nav<3,buff:捕风式,sktest:捉影式,cdtime:捉影式<0.2] 捉影式

　　--释放捉影式之后，禅那加一

　　/var [lastcast:捉影式,v_nav+1;v_nav]v_nav

　　--擒龙诀和金刚怒目同时，存在，使用腰坠

　　/use [buff:擒龙诀&金刚怒目,v_syyz]腰坠

　　--缺蓝就不等擒龙诀，直接开亦枯亦荣了，适用于DPS低的打不起来蓝的和尚们

　　/skill [mana<0.15,v_nav=1,fight,tlife<1,sktest:守缺式,cdtime:亦枯亦荣<0.2]亦枯亦荣

　　--***********有GCD技能部分***********

　　--擒龙诀回豆的判定，如果擒龙诀buff存在的时候，擒龙诀buff的时间接近回豆的时间了，预判回1豆

　　/var [(bufftime:擒龙诀;18)<17,(bufftime:擒龙诀*10)%15] v_qlj

　　/if [v_qlj,(v_qlj<10),v_nav+1]--时间限制为0-10

　　/if [!v_added]--时间段内只加一次

　　/var [v_nav+1] v_nav

　　/var [true] v_added

　　/end

　　/else--时间段外重置加法判定变量

　　/var [false] v_added

　　/end

　　--点了众嗔奇穴的情况下，众嗔快断了的时候，补一个守缺

　　/skill [sktest:守缺式,cdtime:守缺式<0.2,sklv:6596=1,(bufftime:众嗔;3)<2]守缺式

　　--有CWBUFF，无限韦陀

　　/skill [buff:1919]韦陀献杵

　　--阵眼优先守缺

　　/skill [sktest:守缺式,cdtime:守缺式<0.2,buff:天鼓雷音阵]守缺式

　　--上述技能结束之后，如果禅那预想值大于等于3，优先拿云，之后韦陀。

　　--守缺回豆无视，因为进入GCD之后宏就重新判定了。

　　/skill [v_nav>=3,tlife<=0.3,sktest:拿云式]拿云式

　　/skill [v_nav>=3,sktest:韦陀献杵]韦陀献杵

　　--优先守缺，然后横扫，然后普渡,恒河劫沙，然后捕风不用于打断的时候使用捕风

　　/skill [sktest:守缺式]守缺式

　　/skill [sktest:普渡四方;distance<=5] 横扫六合

　　/skill [sktest:普渡四方]普渡四方

　　/skill [sktest:恒河劫沙]恒河劫沙

　　/skill [sktest:捕风式,(!sktest:守缺式;cdtime:守缺式>1.2),tar,(sklv:5911~=1;V_dd=2)]捕风式